五里操盘选股公式
发布时间：2018-03-01
选股公式源码
DIF:=(EMA(C,12)-EMA(C,26));
DEA:=EMA(DIF,9);
MACD:=2*(DIF-DEA);
MJBT:=EXIST((CROSS(DIF,DEA) AND DIF>0) OR CROSS(DIF,0),5) ;
MVOL5:=MA(V,5);
MVOL10:=MA(V,10);
MVOL20:=MA(V,20);
量托:=MVOL5>=MVOL20 AND CROSS(MVOL10,MVOL20) AND REF(MVOL10,1)<REF(MVOL20,1);
VJBT:=EXIST(CROSS(MVOL5,MVOL10) OR 量托,5);
MA5:=MA(C,5);
MA10:=MA(C,10);
MA20:=MA(C,20);
MA60:=MA(C,60);
MA120:=MA(C,120);
T1:=BARSLAST(REF(LONGCROSS(MA60,MA120,55),1));
JJC:=CROSS(MA5,MA10) AND T1<30;
SJBT:=FILTER(MJBT AND JJC AND VJBT,5);
RSV:=(((C-LLV(L,60))/(HHV(H,60)-LLV(L,60)))*100);
K:=SMA(RSV,10,1),COLOR0000FF,LINETHICK1;
D:=SMA(SMA(RSV,10,1),3,1),COLORFFFFFF,LINETHICK1;
J:=SMA(K,10,1),COLOR00FF00,LINETHICK1;
DBU:=(((C/COST(13))<=0.78)*17);
BT01:=LONGCROSS(K,16.18,5) AND D<19.1;
BT02:=LONGCROSS(K,D,8) AND D<16.18;
FTBT:=FILTER(COUNT(BT01 OR BT02,3)=2,3);
BT03:=FILTER(CROSS(K,D) AND EXIST(DBU=17,3),3);
XG01:=SJBT OR FTBT OR BT03;
LC:=REF(C,1);
RSI5:=SMA(MAX(C-LC,0),5,1)/SMA(ABS(C-LC),5,1)*1000;
DC:=RSI5-LLV(RSI5,10);
AV:=(MA(DC,3)*5+DC*15)/20;
DXRSI:=IF(AV>13,MA(AV,3),AV)/6;
MADXRSI:=MA(DXRSI,5),COLORBBBBBB;
DXBT:=CROSS(DXRSI,1) AND DXRSI<30;
ABS34:=MA(-100*(HHV(H,34)-C)/(HHV(H,34)-LLV(L,34)),20);
BS13:=-100*(HHV(H,13)-C)/(HHV(H,13)-LLV(L,13));
EBS5:=EMA(-100*(HHV(H,34)-C)/(HHV(H,34)-LLV(L,34)),5);
VBS13:=BS13+100;
VABS34:=ABS34+100;
VEBS5:=EBS5+100;
底区:=(VABS34<12 AND VEBS5<8 AND (VBS13<7.2 OR REF(VBS13,1)<5) AND (VEBS5>REF(VEBS5,1)
OR VBS13>REF(VBS13,1))) OR (VABS34<8 AND VEBS5<7 AND VBS13<15 AND VBS13>REF(VBS13,1))
OR (VABS34<10 AND VEBS5<7 AND VBS13<1);
低金:=(VABS34<15 AND REF(VABS34,1)<15 AND VEBS5<18 AND VBS13>REF(VBS13,1) AND
CROSS(VBS13,VABS34) AND VBS13>VEBS5 AND (REF(VBS13,1)<5 OR REF(VBS13,2)<5 ) AND
(VEBS5>=VABS34 OR REF( VBS13,1)<1 ));
FZBT:=DXBT AND 低金;
FZXG:=低金 OR FZBT;
VARF11:=(C-MA(C,55))/MA(C,55)*100<-30 AND (C-MA(C,89))/MA(C,89)*100<-27
AND COUNT((C-MA(C,55))/MA(C,55)*100<-30 AND (C-MA(C,89))/MA(C,89)*100<-27,2)=1
AND (O-REF(C,1))/REF(C,1)>-0.07 AND COUNT(C=O,6)=0,COLORCCCCCC;
VARF21:=(C-DMA(EMA(C,8),SUM(V,9)/2.8/CAPITAL))/DMA(EMA(C,8),SUM(V,9)/2.8/CAPITAL)*100,COLOR00AAAA;
VARF31:=REF(VARF21,1)<-46 AND VARF21>REF(VARF21,1) AND
REF(VARF21,1)<REF(VARF21,2) AND VARF21-REF(VARF21,1)>2.2;{-42,1.8}
JDBT1:=(VARF11 OR VARF31)*10,COLOR0000FF,LINETHICK2;
JDBT2:=LONGCROSS(VARF21,-23,3);
JDXG:=JDBT1 OR JDBT2;
XG02:=FILTER(FZXG OR JDXG,5);
XG:=XG01 OR XG02;
{基本面部分}
LTP:=FINANCE(7)<300000000 AND FINANCE(1)<500000000; {流通盘股小于3亿股,总盘小于5亿}
MGSY:=FINANCE(33)>0.02 AND BARSCOUNT(C)>30;
SYL:=C/FINANCE(33)<200 AND C/FINANCE(33)>5; {市盈率低于200}
JZC:=FINANCE(34)>2;{ 每股净资产}
{通达信去掉*、S、ST}
S2:=IF(NAMELIKE('S'),0,1);
S3:=IF(NAMELIKE('*'),0,1);
GJFW:=DYNAINFO(7)>3 AND DYNAINFO(7)<40;{3元-40元价格的股}
XGJ:=LTP AND MGSY AND SYL AND JZC AND S2 AND S3 AND GJFW;
W18:EXIST(XG AND XGJ,3);
选股公式翻译
DIF赋值:(收盘价的12日指数移动平均-收盘价的26日指数移动平均) DEA赋值:DIF的9日指数移动平均 MACD赋值:2*(DIF-DEA) MJBT赋值:最近5日存在(DIF上穿DEAANDDIF>0)ORCROSS(DIF,0) MVOL5赋值:成交量(手)的5日简单移动平均 MVOL10赋值:成交量(手)的10日简单移动平均 MVOL20赋值:成交量(手)的20日简单移动平均 量托赋值:MVOL5>=MVOL20 AND MVOL10上穿MVOL20 AND 1日前的MVOL10<1日前的MVOL20 VJBT赋值:最近5日存在MVOL5上穿MVOL10OR量托 MA5赋值:收盘价的5日简单移动平均 MA10赋值:收盘价的10日简单移动平均 MA20赋值:收盘价的20日简单移动平均 MA60赋值:收盘价的60日简单移动平均 MA120赋值:收盘价的120日简单移动平均 T1赋值:上次1日前的MA60小于MA120保持55个交易日后交叉上穿距今天数 JJC赋值:MA5上穿MA10 AND T1<30 SJBT赋值:MJBTANDJJCANDVJBT的5日过滤 RSV赋值:(((收盘价-60日内最低价的最低值)/(60日内最高价的最高值-60日内最低价的最低值))*100) K赋值:RSV的10日[1日权重]移动平均,COLOR0000FF,线宽为1 D赋值:RSV的10日[1日权重]移动平均的3日[1日权重]移动平均,COLORFFFFFF,线宽为1 J赋值:K的10日[1日权重]移动平均,COLOR00FF00,线宽为1 DBU赋值:(((收盘价/获利盘为13%的成本分布)<=0.78)*17) BT01赋值:K小于16.18保持5个交易日后交叉上穿 AND D<19.1 BT02赋值:K小于D保持8个交易日后交叉上穿 AND D<16.18 FTBT赋值:统计3日中满足BT01ORBT02的天数=2的3日过滤 BT03赋值:K上穿DANDEXIST(DBU=17,3)的3日过滤 XG01赋值:SJBT OR FTBT OR BT03 LC赋值:1日前的收盘价 RSI5赋值:收盘价-LC和0的较大值的5日[1日权重]移动平均/收盘价-LC的绝对值的5日[1日权重]移动平均*1000 DC赋值:RSI5-10日内RSI5的最低值 AV赋值:(DC的3日简单移动平均*5+DC*15)/20 DXRSI赋值:如果AV>13,返回AV的3日简单移动平均,否则返回AV/6 MADXRSI赋值:DXRSI的5日简单移动平均,COLORBBBBBB DXBT赋值:DXRSI上穿1 AND DXRSI<30 ABS34赋值:-100*(34日内最高价的最高值-收盘价)/(34日内最高价的最高值-34日内最低价的最低值)的20日简单移动平均 BS13赋值:-100*(13日内最高价的最高值-收盘价)/(13日内最高价的最高值-13日内最低价的最低值) EBS5赋值:-100*(34日内最高价的最高值-收盘价)/(34日内最高价的最高值-34日内最低价的最低值)的5日指数移动平均 VBS13赋值:BS13+100 VABS34赋值:ABS34+100 VEBS5赋值:EBS5+100 底区赋值:(VABS34<12 AND VEBS5<8 AND (VBS13<7.2 OR 1日前的VBS13<5) AND (VEBS5>1日前的VEBS5OR VBS13>1日前的VBS13)) OR (VABS34<8 AND VEBS5<7 AND VBS13<15 AND VBS13>1日前的VBS13)OR (VABS34<10 AND VEBS5<7 AND VBS13<1) 低金赋值:(VABS34<15 AND 1日前的VABS34<15 AND VEBS5<18 AND VBS13>1日前的VBS13 ANDCROSS(VBS13,VABS34) AND VBS13>VEBS5 AND (1日前的VBS13<5 OR 2日前的VBS13<5 ) AND(VEBS5>=VABS34 OR 1日前的VBS13<1 )) FZBT赋值:DXBT AND 低金 FZXG赋值:低金 OR FZBT VARF11赋值:(收盘价-收盘价的55日简单移动平均)/收盘价的55日简单移动平均*100<-30 AND (收盘价-收盘价的89日简单移动平均)/收盘价的89日简单移动平均*100<-27AND 统计2日中满足(收盘价-收盘价的55日简单移动平均)/收盘价的55日简单移动平均*100<-30AND(收盘价-收盘价的89日简单移动平均)/收盘价的89日简单移动平均*100<-27的天数=1AND (开盘价-1日前的收盘价)/1日前的收盘价>-0.07 AND 统计6日中满足平盘的天数=0,COLORCCCCCC VARF21赋值:(收盘价-以成交量(手)的9日累和/2.8/当前流通股本(手)为权重收盘价的8日指数移动平均的动态移动平均)/以成交量(手)的9日累和/2.8/当前流通股本(手)为权重收盘价的8日指数移动平均的动态移动平均*100,COLOR00AAAA VARF31赋值:1日前的VARF21<-46 AND VARF21>1日前的VARF21 AND 1日前的VARF21<2日前的VARF21 AND VARF21-1日前的VARF21>2.2 JDBT1赋值:(VARF11 OR VARF31)*10,COLOR0000FF,线宽为2 JDBT2赋值:VARF21小于-23保持3个交易日后交叉上穿 JDXG赋值:JDBT1 OR JDBT2 XG02赋值:FZXGORJDXG的5日过滤 XG赋值:XG01 OR XG02 LTP赋值:流通股本(股)<300000000 AND 总股本(股)<500000000 MGSY赋值:每股收益(全年折算)>0.02 AND 收盘价的有效数据周期数>30 SYL赋值:收盘价/每股收益(全年折算)<200 AND 收盘价/每股收益(全年折算)>5 JZC赋值:每股净资产>2 S2赋值:如果模糊匹配品种名称,返回0,否则返回1 S3赋值:如果模糊匹配品种名称,返回0,否则返回1 GJFW赋值:现价>3 AND 现价<40 XGJ赋值:LTP AND MGSY AND SYL AND JZC AND S2 AND S3 AND GJFW 输出W18:最近3日存在XGANDXGJ
演示图片
